ファイル:Cube permutation 0 0 JF.png
![ファイル:Cube permutation 0 0 JF.png](http://upload.wikimedia.org/wikipedia/commons/thumb/9/95/Cube_permutation_0_0_JF.png/600px-Cube_permutation_0_0_JF.png)
元のファイル (4,000 × 4,000 ピクセル、ファイルサイズ: 376キロバイト、MIME タイプ: image/png)
![]() |
ウィキメディア・コモンズのファイルページにある説明を、以下に表示します。
|
概要
解説Cube permutation 0 0 JF.png |
3-dimensional compound of the letters J and F (a figure without internal symmetry) This position illustrates the neutral element among the 48 permutations of the cube.
|
||||||||||||
原典 | 投稿者自身による著作物 | ||||||||||||
作者 |
|
||||||||||||
その他のバージョン |
![]()
|
![]() |
العربية ∙ جازايرية ∙ беларуская ∙ беларуская (тарашкевіца) ∙ български ∙ বাংলা ∙ català ∙ čeština ∙ Cymraeg ∙ Deutsch ∙ Schweizer Hochdeutsch ∙ Zazaki ∙ Ελληνικά ∙ English ∙ Esperanto ∙ español ∙ eesti ∙ euskara ∙ فارسی ∙ suomi ∙ français ∙ galego ∙ עברית ∙ हिन्दी ∙ hrvatski ∙ magyar ∙ հայերեն ∙ Bahasa Indonesia ∙ italiano ∙ 日本語 ∙ Jawa ∙ ქართული ∙ 한국어 ∙ kurdî ∙ Lëtzebuergesch ∙ lietuvių ∙ македонски ∙ മലയാളം ∙ मराठी ∙ Bahasa Melayu ∙ Nederlands ∙ Norfuk / Pitkern ∙ polski ∙ português ∙ português do Brasil ∙ rumantsch ∙ română ∙ русский ∙ sicilianu ∙ slovenčina ∙ slovenščina ∙ shqip ∙ српски / srpski ∙ svenska ∙ தமிழ் ∙ తెలుగు ∙ ไทย ∙ Tagalog ∙ Türkçe ∙ toki pona ∙ українська ∙ vèneto ∙ Tiếng Việt ∙ 中文 ∙ 中文(简体) ∙ 中文(繁體) ∙ +/− |
POV-Ray source
POV-Ray source |
---|
#version 3.6;
global_settings { assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 conserve_energy}}
#include "colors.inc"
#include "math.inc"
///////////////////////////// camera and light
#declare Camera_Position = <12, 12, -50>;
camera{
location Camera_Position
right x*image_width/image_height
angle 6.5
look_at <-0.05, -0.14, -0.07>
}
light_source{ <-400, 500, -300> color White*0.9 shadowless}
light_source{ Camera_Position color rgb<0.9,0.9,1>*0.1 shadowless}
sky_sphere{ pigment{ White } }
///////////////////////////// JF solid
#declare LightColor = rgb<0.6, 0.55, 0.55>;
#declare DarkColor = rgb<0.005, 0.004, 0.004>;
#declare CubeColor = rgb<0.25, 0.25, 0.25>;
#declare BigCyl = cylinder{ <0, 0, 0>, <0.9, 0, 0>, 1.5 }
#declare SmallCyl = cylinder{ <-0.1, 0, 0>, <1, 0, 0>, 0.6 }
#declare Ring = difference{
object{BigCyl}
object{SmallCyl}
}
#declare CutBox = box{
<-10,-10,-10> <10,10,10>
translate 10*y
}
#declare HalfRing = difference{
object{Ring}
object{CutBox}
}
#declare CutBox = object{
CutBox
rotate -45*x
pigment{color DarkColor}
}
#declare LetterJTail = difference{
object{HalfRing}
object{CutBox}
}
#declare LetterStem = box{
<0, 0, 0.6>
<0.9, 2.4, 1.5>
}
#declare LetterFBar1 = box{
<0, 1.5, 0.6>
<-3, 2.4, 1.5>
}
#declare CutBox = box{
<-10,-10,-10> <10,10,10>
translate <-12.6, 0, 0>
pigment{color DarkColor}
}
#declare LetterFBar1 = difference{
object{LetterFBar1}
CutBox
}
#declare LetterFBar2 = object{
LetterFBar1
translate <0, -1.5, 0>
}
#declare CutBox = object{
CutBox
translate <1.3, 0, 0>
}
#declare LetterFBar2 = difference{
object{LetterFBar2}
CutBox
}
#declare LetterJFSolid = union{
object{LetterJTail}
object{LetterStem}
object{LetterFBar1}
object{LetterFBar2}
pigment{color LightColor}
}
///////////////////////////// JF outline
#declare R = 0.03;
#declare PointFBar1a = <0.9, 2.4, 0.6>;
#declare PointFBar1b = PointFBar1a + 0.9*z;
#declare PointFBar1c = PointFBar1a - 3.5*x;
#declare PointFBar1d = PointFBar1b - 3.5*x;
#declare PointFBar2c = PointFBar1c - 0.9*y;
#declare PointFBar2d = PointFBar2c + 0.9*z;
#declare PointFBar2a = PointFBar2c + 2.6*x;
#declare PointFBar2b = PointFBar2a + 0.9*z;
#declare PointFBar3a = PointFBar2a - 0.6*y;
#declare PointFBar3b = PointFBar3a + 0.9*z;
#declare PointFBar3c = PointFBar3a - 1.3*x;
#declare PointFBar3d = PointFBar3b - 1.3*x;
#declare PointFBar4a = PointFBar3a - 0.9*y;
#declare PointFBar4b = PointFBar4a + 0.9*z;
#declare PointFBar4c = PointFBar4a - 1.3*x;
#declare PointFBar4d = PointFBar4b - 1.3*x;
#declare PointJFaceA = PointFBar4a + 0.9*x;
#declare PointJFaceB = PointFBar4b + 0.9*x;
#declare PointJEndA = <0.9, -sqrt(1.125), -sqrt(1.125)>;
#declare PointJEndB = <0.9, -sqrt(0.18), -sqrt(0.18)>;
#declare PointJEndC = PointJEndA - 0.9*x;
#declare PointJEndD = PointJEndB - 0.9*x;
#declare SmallTorus = object{
torus {0.6, R}
rotate 90*z
}
#declare BigTorus = object{
torus {1.5, R}
rotate 90*z
}
#declare Tori1 = union{
object{SmallTorus}
object{BigTorus}
}
#declare Tori2 = object{
Tori1
translate 0.9*x
}
#declare Tori = union{
object{Tori1}
object{Tori2}
}
#declare CutBox = box{
<-10,-10,-10> <10,10,10>
translate 10*y
}
#declare Tori = difference{
object{Tori}
object{CutBox}
}
#declare CutBox = object{
CutBox
rotate -45*x
}
#declare Tori = difference{
object{Tori}
object{CutBox}
}
#declare LetterJFOutlines = union{
sphere{PointFBar1a, R}
sphere{PointFBar1b, R}
sphere{PointFBar1c, R}
sphere{PointFBar1d, R}
sphere{PointFBar2a, R}
sphere{PointFBar2b, R}
sphere{PointFBar2c, R}
sphere{PointFBar2d, R}
sphere{PointFBar3a, R}
sphere{PointFBar3b, R}
sphere{PointFBar3c, R}
sphere{PointFBar3d, R}
sphere{PointFBar4a, R}
sphere{PointFBar4b, R}
sphere{PointFBar4c, R}
sphere{PointFBar4d, R}
sphere{PointJEndA, R}
sphere{PointJEndB, R}
sphere{PointJEndC, R}
sphere{PointJEndD, R}
cylinder{PointFBar1a, PointFBar1b, R}
cylinder{PointFBar1b, PointFBar1d, R}
cylinder{PointFBar1d, PointFBar1c, R}
cylinder{PointFBar1c, PointFBar1a, R}
cylinder{PointFBar2a, PointFBar2b, R}
cylinder{PointFBar2b, PointFBar2d, R}
cylinder{PointFBar2d, PointFBar2c, R}
cylinder{PointFBar2c, PointFBar2a, R}
cylinder{PointFBar3a, PointFBar3b, R}
cylinder{PointFBar3b, PointFBar3d, R}
cylinder{PointFBar3d, PointFBar3c, R}
cylinder{PointFBar3c, PointFBar3a, R}
cylinder{PointFBar4a, PointFBar4b, R}
cylinder{PointFBar4b, PointFBar4d, R}
cylinder{PointFBar4d, PointFBar4c, R}
cylinder{PointFBar4c, PointFBar4a, R}
cylinder{PointFBar1c, PointFBar2c, R}
cylinder{PointFBar1d, PointFBar2d, R}
cylinder{PointFBar2a, PointFBar3a, R}
cylinder{PointFBar2b, PointFBar3b, R}
cylinder{PointFBar3c, PointFBar4c, R}
cylinder{PointFBar3d, PointFBar4d, R}
cylinder{PointFBar1a, PointJFaceA, R}
cylinder{PointFBar1b, PointJFaceB, R}
cylinder{PointJEndA, PointJEndB, R}
cylinder{PointJEndB, PointJEndD, R}
cylinder{PointJEndD, PointJEndC, R}
cylinder{PointJEndC, PointJEndA, R}
object{Tori}
pigment{color DarkColor}
}
///////////////////////////// cube
#declare CubeCoordinates = array[8]{
<-2.25, 2.25, 2.25>,
< 2.25, 2.25, 2.25>,
<-2.25, -2.25, 2.25>,
< 2.25, -2.25, 2.25>,
<-2.25, 2.25, -2.25>,
< 2.25, 2.25, -2.25>,
<-2.25, -2.25, -2.25>,
< 2.25, -2.25, -2.25>
}
#declare CubeEdgesAbstractCoordinates = array[12][2]{
{0,1}, {2,3}, {4,5}, {6,7}, {0,2}, {1,3}, {4,6}, {5,7}, {0,4}, {1,5}, {2,6}, {3,7}
}
#declare Cube = union{
#for(i, 0, 7)
sphere{CubeCoordinates[i], 0.01}
#end
#for(i, 0, 11)
cylinder{
CubeCoordinates[CubeEdgesAbstractCoordinates[i][0]],
CubeCoordinates[CubeEdgesAbstractCoordinates[i][1]],
0.01
}
#end
pigment{color CubeColor}
}
///////////////////////////// show
#declare LetterJF = union{
object{LetterJFSolid}
object{LetterJFOutlines}
translate <0.85, -0.45, -0.25>
rotate 90*y
}
#declare CubeLetterCompound = union{
object{LetterJF}
object{Cube}
}
object{
CubeLetterCompound
}
|
ライセンス
![]() |
この文書は、フリーソフトウェア財団発行のGNUフリー文書利用許諾書 (GNU Free Documentation License) 1.2またはそれ以降のバージョンの規約に基づき、複製や再配布、改変が許可されます。不可変更部分、表紙、背表紙はありません。このライセンスの複製は、GNUフリー文書利用許諾書という章に含まれています。http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
![w:ja:クリエイティブ・コモンズ](https://upload.wikimedia.org/wikipedia/commons/thumb/7/79/CC_some_rights_reserved.svg/90px-CC_some_rights_reserved.svg.png)
![表示](https://upload.wikimedia.org/wikipedia/commons/thumb/1/11/Cc-by_new_white.svg/24px-Cc-by_new_white.svg.png)
- あなたは以下の条件に従う場合に限り、自由に
- 共有 – 本作品を複製、頒布、展示、実演できます。
- 再構成 – 二次的著作物を作成できます。
- あなたの従うべき条件は以下の通りです。
- 表示 – あなたは適切なクレジットを表示し、ライセンスへのリンクを提供し、変更があったらその旨を示さなければなりません。これらは合理的であればどのような方法で行っても構いませんが、許諾者があなたやあなたの利用行為を支持していると示唆するような方法は除きます。
キャプション
このファイルに描写されている項目
題材
ウィキデータ項目がない値
image/png
bfd019c035658236ce9e8fe1e1f5c99b84883411
384,575 バイト
4,000 ピクセル
4,000 ピクセル
ファイルの履歴
過去の版のファイルを表示するには、その版の日時をクリックしてください。
日付と時刻 | サムネイル | 寸法 | 利用者 | コメント | |
---|---|---|---|---|---|
現在の版 | 2017年4月26日 (水) 22:14 | ![]() | 4,000 × 4,000 (376キロバイト) | Watchduck |
ファイルの使用状況
このファイルを使用しているページはありません。
グローバルなファイル使用状況
以下に挙げる他のウィキがこの画像を使っています:
- en.wikiversity.org での使用状況
メタデータ
このファイルには、追加情報があります (おそらく、作成やデジタル化する際に使用したデジタルカメラやスキャナーが追加したものです)。
このファイルが元の状態から変更されている場合、修正されたファイルを完全に反映していない項目がある場合があります。
PNGファイルのコメント |
|
---|---|
ファイル変更日時 | 2017年4月25日 (火) 23:00 |
使用ソフトウェア名 |
|